# Maintainer: Alexey Pavlov <alexpux@gmail.com>

_realname=Alien-Build
pkgname=perl-${_realname}
pkgver=2.84
pkgrel=1
pkgdesc="Build external dependencies for use in CPAN"
arch=('any')
license=('spdx:Artistic-1.0-Perl' 'spdx:GPL-1.0-or-later')
url="https://metacpan.org/dist/Alien-Build"
groups=('perl-modules')
depends=('perl-Capture-Tiny' 'perl-FFI-CheckLib' 'perl-File-chdir' 'perl-File-Which' 'perl-Path-Tiny')
makedepends=('perl-Test2-Suite' 'perl-devel')
#checkdepends=('perl-Alien-Base-ModuleBuild' 'perl-Alien-cmake3' 'perl-Env-ShellWords'
#              'perl-PkgConfig' 'perl-PkgConfig-LibPkgConf' 'perl-Readonly' 'perl-Sort-Versions')
options=(!emptydirs)
source=("https://cpan.metacpan.org/authors/id/P/PL/PLICEASE/${_realname}-${pkgver}.tar.gz"
        01-msysize.patch)
options=(!emptydirs)
sha256sums=('8e891fd3acbac39dd8fdc01376b9abff931e625be41e0910ca30ad59363b4477'
            '483769e64ca04e7005fb743e3500561ab8fd49ca9ee239fd5dd96045dc9677a2')

prepare() {
  cd ${srcdir}/${_realname}-${pkgver}
  patch -p1 -i ${srcdir}/01-msysize.patch
}

build() {
  cd ${srcdir}/${_realname}-${pkgver}

  # install module in vendor directories.
  perl Makefile.PL -- INSTALLDIRS=vendor
  make
}

check() {
  cd ${_realname}-${pkgver}
  make test
}

package() {
  cd ${srcdir}/${_realname}-${pkgver}

  make install DESTDIR=${pkgdir}
  # Remove .packlist and perllocal.pod files.
  find "$pkgdir" -name '.packlist' -delete
  find "$pkgdir" -name 'perllocal.pod' -delete
}
